home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Cream of the Crop 22
/
Cream of the Crop 22.iso
/
os2
/
ftree11a.zip
/
WEDDINGS.FTX
< prev
Wrap
Text File
|
1996-10-30
|
3KB
|
113 lines
/*
Family Tree Rexx Script FTX
Copyright (C) 1996 by <Nils Meier>
Please send comments to / Kommentar bitte an
meier2@athene.informatik.uni-bonn.de
<
English: This script shows all wedding aniversaries in this year. :English
Deutsch: Dieses Skript zeigt die Heiratsjubiläen in diesem Jahr. :Deutsch
Nederlands: This script shows all wedding aniversaries in this year. :Nederlands
Francais: Ce script donne tous les anniversaires de mariage dans l'année.:Francais
>
Long name is <
English: List wedding aniversaries :English
Deutsch: Auflisten der Heiratsjubiläen :Deutsch
Nederlands: List weddings aniversaries :Nederlands
Francais: Imprime anniversaires de mariage :Francais
>
*/
/* ----------------------- Params / Parameter ------------------- */
datewidth=14
yearwidth=datewidth+9
CALL InitLanguage
/* -------------------------- Output / Ausgabe --------------------- */
SAY(msg.Header.LANG)
SAY(COPIES('=',length(msg.Header.LANG)))
/* Sort Families by Date Month,Day / Familien nach Monat,Tag sortieren */
rc=sortFamilies('MM,MD')
/* Calculate actual year / aktuelles Jahr berechnen */
thisyear=WORD(DATE(),3)
/* Display families in tree / Familien ausgeben */
rc=selectFamily('F')
DO WHILE rc=1
/* Get month / berechne Monat */
result=getMarriageDate('m')
/* Check if we've got a month / nachpruefen ob wir Monat haben */
IF result<>'?' THEN DO
/* Get Day / berechne Tag */
day=getMarriageDate('D')
if day<>0 THEN
result=result||' '||day
result=LEFT(result,datewidth)
/* Add anniversary / plus Jahrestag */
year=getMarriageDate('Y')
IF year<>0 THEN
result=result||' ('||thisyear-year||')'
result=LEFT(result,yearwidth)
/* Add name,first name / plus Name,Vorname */
rc=selectPerson('f')
result=result||getName()||','||getFirstName()
rc=selectPerson('m')
result=result||' - '||getName()||','||getFirstName()
/* output / Ausgabe */
SAY(result)
END
/* Next one */
rc=selectFamily('N')
END
/* Done */
RETURN
/* ---------------------- LANGUAGE INIT --------------------------- */
InitLanguage:
/* Calculate Language Index */
lang='E' /* Default -> [E]nglish */
IF getLanguage()='Deutsch' THEN /* Deutsch -> [G]erman */
lang='G'
IF getLanguage()='Nederlands' THEN /* Nederlands -> [D]utch */
lang='D'
IF getLanguage()='Francais' THEN /* Francais -> [F]rench */
lang='F'
/* [E]nglish Messages */
msg.Header.E='Wedding Anniversary this year (next anniversary) '
/* [G]erman Messages */
msg.Header.G='Heiratsjubilaeum in diesem Jahr (Jahrestag) '
/* [D]utch Messages */
msg.Header.D='Wedding Anniversary this year (next anniversary) '
/* [F]rench Messages */
msg.Header.F="Anniversaires de mariage cette année (prochains anniversaires) "
/* Done */
RETURN